SPARQL playground

Área del desarrollador

Consultas SPARQL

SPARQL endpoint

Las consultas SPARQL se pueden hacer directamente en el SPARQL endpoint de sólo lectura: http://guerracivileuskadi.eurohelp.es/blazegraph/#query.

Ejemplos

A continuación se muestran algunas consultas SPARQL de ejemplo. Estos ejemplos se pueden ejecutar pinchando en el enlace "DESCARGAR DATOS" o copiando y pegando la consulta en el SPARQL endpoint:

Leyes emitidas por el "Gobierno Provisional de Euzkadi" sobre alistamiento

PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/> 
PREFIX eli: <http://data.europa.eu/eli/ontology#> 
PREFIX graph: <http://data.euskadi.eus/graph/>
PREFIX dbo: <http://dbpedia.org/ontology/>


SELECT  DISTINCT ?datePub ?legeguneaurl ?title
WHERE {
	?legalresource dbo:date ?datePub .
	?legalresource eli:is_realized_by ?legalexpresion .
	?legalexpresion eli:language  <http://publications.europa.eu/resource/authority/language/SPA> .
	?legalexpresion eli:title ?title .
	?eliformat eli:embodies ?legalexpresion .
	?eliformat schema:mainEntityOfPage ?legeguneaurl .
	FILTER (?datePub > "1936-07-18"^^xsd:date  && ?datePub < "1937-07-31"^^xsd:date)
	FILTER regex (str(?title), "alistamiento", "i")
}

Descargar datos

¿Cuál es el actual partido político en el poder en localidades con fosas comunes?

PREFIX dbo:<http://dbpedia.org/ontology/>
PREFIX schema:<http://schema.org/>
PREFIX rdf:<http://www.w3.org/1999/02/22-rdf-syntax-ns#>
PREFIX rdfs:<http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT *
WHERE {
   ?fosa rdf:type <http://rdf.muninn-project.org/ontologies/graves#Mass_grave> .
	?fosa schema:location ?pueblofosa .
	SERVICE <https://dbpedia.org/sparql> {
		?pueblofosa dbo:leaderParty ?party .
	}
}

Descargar datos

De las causas de muerte recogidas en los datos de desapariciones, ¿cuántos muertos causó cada una por tipo?

SELECT ?mode (COUNT(?person) as ?numeroMode)
WHERE {
?person <http://guerracivileuskadi.eurohelp.es/linkeddata/def/euskadipedia/death-mode> ?mode
}
GROUP BY ?mode
ORDER BY (?numeroMode)

Descargar datos

Bombardeos del bando Franquista

PREFIX dbp: <http://dbpedia.org/property/>
PREFIX dbr: <http://dbpedia.org/resource/>
PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX schema: <http://schema.org/>
SELECT * 
WHERE { 
	?bombardment dbp:plannedBy dbr:Francoist_Spain .
	?bombardment geo-pos:lat ?latitude .
	?bombardment geo-pos:long ?longitude .
	?bombardment dbo:date ?date .
	?bombardment schema:location ?location .
}

Descargar datos

Bombardeos de la Legión Cóndor

SELECT  DISTINCT ?location ?date ?source ?comment
WHERE {
	?bombing rdf:type <http://dbpedia.org/resource/Aerial_bombing_of_cities> .
	?bombing <http://schema.org/location> ?location .
	?bombing <http://dbpedia.org/ontology/date> ?date .         
	?bombing rdfs:comment ?comment .
	?bombing <http://purl.org/dc/terms/source> ?source
	FILTER regex (str(?source), "Cóndor", "i")
}
ORDER BY ?date

Descargar datos

Eventos de un rango de fechas

PREFIX dbo: <http://dbpedia.org/ontology/>
PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT ?evento 
WHERE { 
	?evento dbo:date ?date .
    FILTER (?date > "1937-05-06"^^xsd:date  && ?date < "1937-07-31"^^xsd:date)        
}

Descargar datos

Fosas comunes en una área, su población, y la página wikipedia de esa población

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
PREFIX geo-pos: <http://www.w3.org/2003/01/geo/wgs84_pos#>
PREFIX xsd: <http://www.w3.org/2001/XMLSchema#>
PREFIX schema: <http://schema.org/>

SELECT ?place ?location ?web WHERE { 
	?place geo-pos:lat ?latitude .
	?place geo-pos:long ?longitude .
	?place schema:location ?location .
	SERVICE <http://dbpedia.org/sparql> {
		?location foaf:isPrimaryTopicOf ?web .
	}
	FILTER (?latitude > "42.1"^^xsd:double  && ?latitude < "42.99"^^xsd:double)
	FILTER (?longitude < "-2.5"^^xsd:double  && ?longitude > "-2.9"^^xsd:double)
}

Descargar datos

DBpedia

Datos de la DBpedia almacenados, y su página web:

PREFIX foaf: <http://xmlns.com/foaf/0.1/>
SELECT * 
WHERE { 
    ?dbpediaresource foaf:isPrimaryTopicOf ?dbpediaurl
}

Descargar datos

Consulta DBpedia para extraer datos sobre la guerra civil en Euskadi

PREFIX dcterms:<http://purl.org/dc/terms/>

SELECT ?x WHERE{
   ?x dcterms:subject <http://es.dbpedia.org/resource/Categoría:Guerra_Civil_Española_en_el_País_Vasco> 
}

Descargar datos

Descarga completa de datos

Todos los datos en RDF Turtle.

Herramientas usadas

Triple Store: Blazegraph. La Triple Store se despliega como un war de solo lectura en un container Docker que incluye Tomcat.

Transformación de datos a RDF: OntoRefine de GraphDB.

Reconciliación de entidades con DBPedia: Open Refine con plugin RDF.

Fuente de fotos: Fuente de fotos.

Repositorio GitHub: GuerraCivilEuskadi.